课件来源处

前言

一、在代码段中使用数据

一个题目

考虑这样一个问题，编程计算以下8个数据的和，结果存在ax 寄存器中：
0123H，0456H，0789H，0abcH，0defH，0fedH，0cbaH，0987H。

分析

我们可以将它们一个一个地加到ax寄存器中，但是，我们希望可以用循环的方法来进行累加，所以在累加前，要将这些数据存储在一组地址连续的内存单元中。如何将这些数据存储在一组连续的内存单元中呢？我们可以用指令一个一个地将它们送入地址连续的内存单元中，可是这样又有一个问题，到哪里去找这段内存空间呢？

assume cs:codesg
codesg segment
	dw 0123h,0456h,0789h,0abch,0defh,0fedh,0cbah,0987h
  	mov bx,0
	mov ax,0
	mov cx,8
 s: add ax,cs:[bx]
	add bx,2
	loop s
	mov ax,4c00h
	int 21h
codesg ends
end

将程序6.1编译、连接，但不运行

结论

出现问题

程序6.2

assume cs:codesg
codesg segment
	dw 0123h,0456h,0789h,0abch,0defh,0fedh,0cbah,0987h
  start: mov bx,0
     	mov ax,0
	       mov cx,8
        s: add ax,cs:[bx]
	       add bx,2
     	loop s
	       mov ax,4c00h
     	int 21h
codesg ends
end start

end的作用

end 除了通知编译器程序结束外，还可以通知编译器程序的入口在什么地方。

回顾程序执行过程

确定第一条指令

程序描述框架

二、在代码段中使用栈

任务

写出程序

assume cs:codesg
codesg segment
	dw 0123H,0456H,0789H,0abcH,0defH,0fedH,0cbaH,0987H
	dw 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0  	
				;用dw定义8个字型数据，在程序加载后，将取得8个字的
			    	;内存空间，存放这8个数据。我们在后面的程序中将这段
			    	;空间当作栈来使用。
  start: mov ax,cs		
	 mov ss,ax
	 mov sp,30h		;设置栈顶ss:sp指向cs:30

	 mov bx,0
	 mov cx,8
      s: push cs:[bx]
	 add bx,2
	 loop s			;以上将代码段0~15单元中的8个字型数据依次入栈

	 mov bx,0
	 mov cx,8
     s0: pop cs:[bx]
	 add bx,2
	 loop s0		;以上依次出栈8个字型数据到代码段0~15单元中
	 mov ax,4c00h
	 int 21h
codesg ends
end start			;指明程序的入口在start处

注意

cs：10~cs：2f这一段内存空间中数据都是0，我们正好把这一段当做空栈
一个0代表一个字，两个字节，32个内存空间。不是一个0代表一个字节，16个内存空间。
ss：sp指向cs：30
我们定义这些数据的最终目的是：通过它们取得一定容量的内存空间

检测点6.1

答案在此处

三、将数据、代码、栈放入不同的段

程序6.4

assume cs:code,ds:data,ss:stack

data segment
  dw 0123H,0456H,0789H,0abcH,0defH,0fedH,0cbaH,0987H
data ends

stack segment
  dw 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
stack ends

code segment
start:mov ax,stack
      mov ss,ax
      mov sp,20h	;设置栈顶ss:sp指向stack:20
      
      mov ax,data
      mov ds,ax		;ds指向data段
      
      mov bx,0		;ds:bx指向data段中的第一个单元
      
      mov cx,8
    s:push [bx]
      add bx,2
      loop s		;以上将data段中的0~16单元中的8个字型数据依次入栈

      mov bx,0
      mov cx,8
   s0:pop [bx]
      add bx,2
      loop s0		;以上使8个字型数据依次出栈并送到data段的0~16单元中

      mov ax,4c00h
      int 21h
code ends
end start

程序6.4的说明

1.

2.

data、stack段中有很多地址。当然我们这个段本身也应该有一个地址，不然我们怎么知道data、statck段在哪里呢

3."代码段“、“数据段”、“栈段”完全是我们的安排

结论

assume cs:b,ds:a,ss:c

a segment
  dw 0123H,0456H,0789H,0abcH,0defH,0fedH,0cbaH,0987H
a ends

c segment
  dw 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
c ends

b segment
d:    mov ax,c
      mov ss,ax
      mov sp,20h	;设置栈顶ss:sp指向c:20
      
      mov ax,a
      mov ds,ax		;希望用ds:bx访问a段中的数据，ds指向a段

      mov bx,0		;ds:bx指向a段中的第一个单元
      mov cx,8
    s:push [bx]
      add bx,2
      loop s		;以上将a段中的0~15单元中的8个字型数据依次入栈

      mov bx,0
      mov cx,8
   s0:pop [bx]
      add bx,2
      loop s0		;以上使8个字型数据依次出栈并送到a段的0~15单元中

      mov ax,4c00h
      int 21h
b ends
end d