Unity Shader 透视效果/XRay

当人物被建筑遮挡时，为了继续显示人物，一种方法是将人物透过建筑显示为一种颜色。基本原理是在一个pass通道中进行深度测试，当发现被遮挡时使用该pass通道显示一个颜色。

Shader "Test"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}//纹理贴图
		_Diffuse("Color", Color) = (1,1,1,1)//漫反射
		_XRayColor("XRayColor", Color) =(1,1,1,1)//透视显示颜色
		_XRayPower("XRayPower", Range(0.0001,3)) = 1//透视显示系数
    }

    SubShader
    {
        Tags {"Queue"= "Geometry+1000" "RenderType"="Opaque" }//Geometry+1000是为了在其它不透明物体之后再渲染，"+"不要有空格。
        LOD 100

		Pass//透视
		{
			Name "XRay"
			Tags{ "ForceNoShadowCasting" = "true" }//为true表示不受其它物体投掷阴影影响
			Blend SrcAlpha One//颜色混合模式。当该pass通道返回颜色为0时完全使用原颜色缓冲的颜色
			ZWrite Off //关闭深度写入
			ZTest Greater //深度测试，选择在深度更大时渲染本pass。并且因为已经关闭了深度写入，通过本深度测试时不会进行深度写入。
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"

			fixed4 _XRayColor;
			float _XRayPower;

			struct v2f
			{
				float4 vertex : SV_POSITION;
				float3 viewDir : TEXCOORD0;
				float3 normal : TEXCOORD1;
			};

			v2f vert(appdata_base v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.normal = v.normal;
				o.viewDir = ObjSpaceViewDir(v.vertex);
				return o;
			}

			fixed4 frag(v2f i):SV_Target
			{
				float3 normal = normalize(i.normal);//模型空间法线方向
				float3 viewDir = normalize(i.viewDir);//模型空间视野方向
				float rim = 1 - dot(normal,viewDir);//使得在边缘时rim接近1，产生边缘颜色更深的一个效果
				return fixed4(_XRayColor.rgb * pow(rim, 1/_XRayPower),1);//用_XRayPower或 1/_XRayPower都行
			}
			ENDCG
		}

		

        Pass//普通显示
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
			#include "Lighting.cginc"

			sampler2D _MainTex;
            float4 _MainTex_ST;
			float4 _Diffuse;

            struct v2f
            {
				float4 vertex : SV_POSITION;
                float2 uv : TEXCOORD0;
                fixed3 worldNormal:TEXCOORD1;
				float3 worldPos: TEXCOORD2;//世界空间顶点
            };



            v2f vert (appdata_base v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;//环境光

                fixed4 albedo = tex2D(_MainTex, i.uv);//纹理图片颜色值

				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));//世界空间光源方向
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));

				//漫反射
				fixed3 diffuse = _LightColor0.rgb * albedo * _Diffuse.rgb ;

                return float4( ambient + diffuse,1);
            }
            ENDCG
        }
    }
	FallBack "Diffuse"
}